# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit desktop xdg-utils

DESCRIPTION="Git Client, done Sublime."
HOMEPAGE="https://www.sublimemerge.com"
SRC_URI="https://download.sublimetext.com/sublime_merge_build_${PV}_x64.tar.xz"
LICENSE="Sublime"
SLOT="0"
KEYWORDS="~amd64"
IUSE="dbus"
RESTRICT="bindist mirror strip"

RDEPEND="
	dev-libs/glib:2
	x11-libs/gtk+:3
	x11-libs/libX11
	dbus? ( sys-apps/dbus )"

QA_PREBUILT="*"
S="${WORKDIR}/sublime_merge"

MY_PN="sublime_merge"

src_install() {
	insinto /opt/${MY_PN}
	doins -r Icon Packages
	doins changelog.txt

	exeinto /opt/${MY_PN}
	doexe crash_reporter git-credential-sublime ssh-askpass-sublime sublime_merge
	dosym /opt/${MY_PN}/sublime_merge /usr/bin/sublime_merge

	local size
	for size in 16 32 48 128 256; do
		dosym /opt/${MY_PN}/Icon/${size}x${size}/sublime-merge.png \
			/usr/share/icons/hicolor/${size}x${size}/apps/sublime_merge.png
	done

	make_desktop_entry "sublime_merge %F" "Sublime Merge ${PV}" sublime_merge \
		"Development;RevisionControl" "StartupNotify=true"

	# needed to get WM_CLASS lookup right
	mv "${ED}"/usr/share/applications/sublime_merge{-sublime-merge,}.desktop || die
}

pkg_postrm() {
	xdg_icon_cache_update
}

pkg_postinst() {
	xdg_icon_cache_update
}