From 3375f1127733fa47e62317db91e7c631acd078cf Mon Sep 17 00:00:00 2001
From: Martinez <overwatch@covalent.cz>
Date: Mon, 4 Jul 2016 22:12:28 +0200
Subject: [PATCH] add Audacious 3.7.2 and plugins

---
 media-plugins/audacious-plugins/Manifest      |   3 +
 .../audacious-plugins-3.7.2.ebuild            | 173 ++++++++++++++++++
 media-sound/audacious/Manifest                |   4 +
 media-sound/audacious/audacious-3.7.2.ebuild  |  81 ++++++++
 4 files changed, 261 insertions(+)
 create mode 100644 media-plugins/audacious-plugins/Manifest
 create mode 100644 media-plugins/audacious-plugins/audacious-plugins-3.7.2.ebuild
 create mode 100644 media-sound/audacious/Manifest
 create mode 100644 media-sound/audacious/audacious-3.7.2.ebuild

diff --git a/media-plugins/audacious-plugins/Manifest b/media-plugins/audacious-plugins/Manifest
new file mode 100644
index 0000000..f2feafa
--- /dev/null
+++ b/media-plugins/audacious-plugins/Manifest
@@ -0,0 +1,3 @@
+DIST audacious-plugins-3.7.2-gtk3.tar.bz2 1840180 SHA256 5b6c17b6f97ec0e123c59af16b71de6da0ed79327d21fcba9865a8742950b33f SHA512 4fe9f34364f69c132a83fae3d2ff0a13eda6b64615366a4137573118d82ef0a3e3ed0f6b3bae46b5205b57010ccda1ef72715cc5694adb5406f84a9c43424c13 WHIRLPOOL 54928fe14a6684294e16aef360c0af3dbda130b5280e34d7bfaa9b07baf95ff840f87eeb602d74f96405c45682e5e6320462c5007a7e61b8fab7a1a502de74b7
+DIST audacious-plugins-3.7.2.tar.bz2 1839881 SHA256 fcf7488f01781c8f51e0af5cabacdd582b22537a0085f26aa5ca636373f8e1ff SHA512 20bb5b6c777fd6b8bb7a4789bc638faa4146aa7d39c099fe2c2ccd3c919e3548a6a387cd5fa39003cbb4e02e9d78b49461943135e24ee6dabac9eedd3394ba97 WHIRLPOOL d31107a23c96b675ea1234a3f5bcaf65bdaf07ee8e8c400940e7b8b759c93917abcdee5e31ad35d2f7d286568d404cc5f9f562497b0875903baa16d04186b1d5
+EBUILD audacious-plugins-3.7.2.ebuild 4666 SHA256 1bdaee46337163346fa8a8520d47bebe52712449f248b0ab1672280ab224e37f SHA512 d16053970428c72e743026adac70e5fde138b764be47576fc73ae26caf8f5cff269b199a3e3b0288dcf7d591fbfc10744f0be711bd7c4d025502b6b46e8e223a WHIRLPOOL ab2850928de8f27f0f1d6867a1d1c71128d56f960926cad78b08ba25f095143ad8856ec1bcbc774e75ce33f248cec8a85771b49e03580e3cece0808fd73d8ac8
diff --git a/media-plugins/audacious-plugins/audacious-plugins-3.7.2.ebuild b/media-plugins/audacious-plugins/audacious-plugins-3.7.2.ebuild
new file mode 100644
index 0000000..d16040f
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-3.7.2.ebuild
@@ -0,0 +1,173 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="!gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}.tar.bz2 )
+	 gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}-gtk3.tar.bz2 )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux"
+IUSE="aac +adplug alsa bs2b cdda cue ffmpeg flac fluidsynth gnome http gtk gtk3 jack
+lame libnotify libsamplerate lirc mms mp3 nls pulseaudio qt5 scrobbler sdl sid sndfile vorbis wavpack"
+REQUIRED_USE="
+	^^ ( gtk gtk3 qt5 )
+"
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+#   alarm
+#   albumart
+#   delete-files
+#   ladspa
+#   playlist-manager
+#   search-tool
+#   skins
+#   vtx
+# Plugins with a configure option:
+#   glspectrum
+#   gtkui
+#   hotkey
+#   notify
+#   statusicon
+
+RDEPEND="app-arch/unzip
+	>=dev-libs/dbus-glib-0.60
+	dev-libs/libxml2:2
+	media-libs/libmodplug
+	~media-sound/audacious-${PV}
+	>=media-sound/audacious-3.7.1-r1
+	( || ( >=dev-libs/glib-2.32.2[utils] dev-util/gdbus-codegen ) )
+	aac? ( >=media-libs/faad2-2.7 )
+	adplug? ( media-libs/adplug )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	bs2b? ( media-libs/libbs2b )
+	cdda? ( >=media-libs/libcddb-1.2.1
+		dev-libs/libcdio-paranoia )
+	cue? ( media-libs/libcue )
+	ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
+	flac? ( >=media-libs/libvorbis-1.0
+		>=media-libs/flac-1.2.1-r1 )
+	fluidsynth? ( media-sound/fluidsynth )
+	http? ( >=net-libs/neon-0.26.4 )
+	gtk? ( x11-libs/gtk+:2
+		   ~media-sound/audacious-${PV}[gtk?] )
+	gtk3? ( x11-libs/gtk+:3
+			media-libs/adplug
+			~media-sound/audacious-${PV}[gtk3?] )
+	qt5? ( dev-qt/qtcore:5
+		   dev-qt/qtgui:5
+		   dev-qt/qtmultimedia:5
+		   dev-qt/qtwidgets:5
+		   media-libs/adplug
+		   ~media-sound/audacious-${PV}[qt5?] )
+	jack? ( >=media-libs/bio2jack-0.4
+		media-sound/jack-audio-connection-kit )
+	lame? ( media-sound/lame )
+	libnotify? ( x11-libs/libnotify )
+	libsamplerate? ( media-libs/libsamplerate )
+	lirc? ( app-misc/lirc )
+	mms? ( >=media-libs/libmms-0.3 )
+	mp3? ( >=media-sound/mpg123-1.12.1 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
+	scrobbler? ( net-misc/curl )
+	sdl? ( media-libs/libsdl[sound] )
+	sid? ( >=media-libs/libsidplayfp-1.0.0 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	vorbis? ( >=media-libs/libvorbis-1.2.0
+		  >=media-libs/libogg-1.1.3 )
+	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )"
+
+DEPEND="${RDEPEND}
+	nls? ( dev-util/intltool )
+	virtual/pkgconfig"
+
+mp3_warning() {
+	if ! use mp3 ; then
+		ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+	fi
+}
+
+src_unpack() {
+	default
+	if use gtk3 ; then
+		mv "${MY_P}-gtk3" "${MY_P}"
+	fi
+}
+
+src_prepare() {
+	has_version "<dev-libs/glib-2.32" && \
+		cd "${S}"/src/mpris2 && \
+		gdbus-codegen --interface-prefix org.mpris. \
+			--c-namespace Mpris --generate-c-code object-core mpris2.xml && \
+		gdbus-codegen --interface-prefix org.mpris. \
+			--c-namespace Mpris \
+			--generate-c-code object-player mpris2-player.xml && \
+		cd "${S}"
+}
+
+src_configure() {
+	mp3_warning
+	if use qt5 ;then
+		notify="--disable-notify"
+	elif use libnotify ;then
+		notify="--enable-notify"
+	fi
+
+	if use gtk ;then
+		gtk="--enable-gtk"
+	elif use gtk3 ;then
+		gtk="--enable-gtk"
+	else
+		gtk="--disable-gtk"
+	fi
+
+	if use ffmpeg && has_version media-video/ffmpeg ; then
+		ffmpeg="--with-ffmpeg=ffmpeg"
+	elif use ffmpeg && has_version media-video/libav ; then
+		ffmpeg="--with-ffmpeg=libav"
+	else
+		ffmpeg="--with-ffmpeg=none"
+	fi
+
+	econf \
+		${ffmpeg} \
+		${gtk} \
+		${notify} \
+		--enable-modplug \
+		--enable-statusicon \
+		--disable-soxr \
+		$(use_enable adplug) \
+		$(use_enable aac) \
+		$(use_enable alsa) \
+		$(use_enable bs2b) \
+		$(use_enable cdda cdaudio) \
+		$(use_enable cue) \
+		$(use_enable flac flacng) \
+		$(use_enable fluidsynth amidiplug) \
+		$(use_enable flac filewriter_flac) \
+		$(use_enable http neon) \
+		$(use_enable jack) \
+		$(use_enable gnome gnomeshortcuts) \
+		$(use_enable lame filewriter_mp3) \
+		$(use_enable libsamplerate resample) \
+		$(use_enable lirc) \
+		$(use_enable mms) \
+		$(use_enable mp3) \
+		$(use_enable nls) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable qt5 qt) \
+		$(use_enable scrobbler scrobbler2) \
+		$(use_enable sdl sdlout) \
+		$(use_enable sid) \
+		$(use_enable sndfile) \
+		$(use_enable vorbis) \
+		$(use_enable wavpack)
+}
diff --git a/media-sound/audacious/Manifest b/media-sound/audacious/Manifest
new file mode 100644
index 0000000..d57c7b2
--- /dev/null
+++ b/media-sound/audacious/Manifest
@@ -0,0 +1,4 @@
+DIST audacious-3.7.2-gtk3.tar.bz2 573269 SHA256 bf9ce9e2f475d14cf6510e14235e858a73afb67826b039c2b6e0f86851ec7edf SHA512 a34fa2c7509c87e626538eb8c5e8e7136e1f8a9f58e1ade80a6b8805d9586ebcafeab6e58602b642316bd61964ff755aa122b4f295f94817613ad2ba645806a9 WHIRLPOOL 5ea872a087d15d872691a44c0cfd5c105936952588d77aad06403c08d98f003b03d2ac22320c178aaf3abb414fe765ad10db3efb13040b0f935a9675b067af90
+DIST audacious-3.7.2.tar.bz2 572437 SHA256 04f9eaba4522ce9674e6ed8afc7bd6b5fa9a1e240f8090589fc1874f6659f340 SHA512 6cab703dfab9d1479ddf94f6fb71cef961adaa45c56568a211a11851c0ec6a736e81080cc3673f6e1b131245147c55af32ab8eeb9ba1773b07b675ab658d6747 WHIRLPOOL 27043fc2c2084902556b20ba7b3ea907ff7ec32354b2d26c861ef95a97c2f8291d7f811f22d9e542ebe6973682ab15ae9b1ce7bdd1b7d9b449196ef3718d57f7
+DIST gentoo_ice-xmms-0.2.tar.bz2 51839 SHA256 d1be63368b76f4a8b1d5b0e955cd7a77177f56a7f0b828c6603d8fd2836422b1 SHA512 e863a8f86073007c47ce8c20739aae4bff22e22a7ddc11556b12ae6ebb68654cec7310fdc9d05f2c47f81cf2591fe601b2eb12a2fd911c0a6118c9f3cc524f05 WHIRLPOOL b7a4409629a860021477f34f8886c40c005ea2ec34373d80e6a696323866e54f361e38c76b1ac536775ae5912308f11416e613dec791f21473f01a2fad35bcfd
+EBUILD audacious-3.7.2.ebuild 1941 SHA256 daca7599f2c11a46d59b80e8998feebe112ca63ec17c0ba208f84e7bee632d68 SHA512 18ba0100fcd3a6deec5f8095b0ecd2cae1a17dddcc43035afe8a94da59ddd231b509e0e8f834070d58b650e87e18e4f7e8fc074c831ede3f70ae94c3d93ab0e0 WHIRLPOOL 7566bf082187610c4cdd0894073d4724a234a7712d5687855fffc5b902dbb081e1f840fa3df9a806093790c4306550b3b5a0d1340e571e81db0f395bad2bfe62
diff --git a/media-sound/audacious/audacious-3.7.2.ebuild b/media-sound/audacious/audacious-3.7.2.ebuild
new file mode 100644
index 0000000..c84797d
--- /dev/null
+++ b/media-sound/audacious/audacious-3.7.2.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="!gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}.tar.bz2 )
+	 gtk3? ( http://distfiles.audacious-media-player.org/${MY_P}-gtk3.tar.bz2 )
+	 mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux"
+
+IUSE="+chardet nls gtk gtk3 qt5"
+REQUIRED_USE="
+	^^ ( gtk gtk3 qt5 )
+"
+DOCS="AUTHORS"
+
+RDEPEND=">=dev-libs/dbus-glib-0.60
+	>=dev-libs/glib-2.28
+	>=x11-libs/cairo-1.2.6
+	>=x11-libs/pango-1.8.0
+	virtual/freedesktop-icon-theme
+	chardet? ( >=app-i18n/libguess-1.2 )
+	gtk?  ( x11-libs/gtk+:2 )
+	gtk3? ( x11-libs/gtk+:3 )
+	qt5? ( dev-qt/qtcore:5
+	      dev-qt/qtgui:5
+	      dev-qt/qtwidgets:5 )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )"
+
+PDEPEND="~media-plugins/audacious-plugins-${PV}"
+
+src_unpack() {
+	default
+	if use gtk3 ; then
+		mv "${MY_P}-gtk3" "${MY_P}"
+	fi
+}
+
+src_configure() {
+	if use gtk ;then
+		gtk="--enable-gtk"
+	elif use gtk3 ;then
+		gtk="--enable-gtk"
+	else
+		gtk="--disable-gtk"
+	fi
+	# D-Bus is a mandatory dependency, remote control,
+	# session management and some plugins depend on this.
+	# Building without D-Bus is *unsupported* and a USE-flag
+	# will not be added due to the bug reports that will result.
+	# Bugs #197894, #199069, #207330, #208606
+	econf \
+		--enable-dbus \
+		${gtk} \
+		$(use_enable chardet) \
+		$(use_enable nls) \
+		$(use_enable qt5 qt)
+}
+
+src_install() {
+	default
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins "${WORKDIR}"/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}